$TITLE  OECD wholesale and retial trade application


SETS
i                observations /i1*i14/
t                time periods /t1*t29/
;

alias(i,j)
alias(t,s);


PARAMETERS
Y(i,t)           output
L(i,t)          labor
K(i,t)           capital
M(i,t)          intermediate input
Tr(t)           trend
Tr2(t)          trend-squared

SSvalue                     additional export var for SS
Evalue(i,t)                    additional export var for E
BLvalue(i,t)                    additional export var for BL
BKvalue(i,t)                    additional export var for BK
BMvalue(i,t)                    additional export var for BII
ALvalue
CLvalue
AKvalue
CKvalue
AMvalue
CMvalue
Avalue(i)
Bvalue(i)
Cvalue(i)
;



$libinclude xlimport Y C:\GAMS\GAMSFILES\tradesector\output.xls a1:ad15
$libinclude xlimport L C:\GAMS\GAMSFILES\tradesector\labor.xls a1:ad15
$libinclude xlimport K C:\GAMS\GAMSFILES\tradesector\capital.xls a1:ad15
$libinclude xlimport M C:\GAMS\GAMSFILES\tradesector\intinput.xls a1:ad15
$libinclude xlimport Tr C:\GAMS\GAMSFILES\tradesector\T.xls a1:ac2
$libinclude xlimport Tr2 C:\GAMS\GAMSFILES\tradesector\T2.xls a1:ac2
;




VARIABLES
E(i,t)             error term
SS              sum of square of errors
AL              labor trend
CL              labor trend
AK              capital trend
CK              capital trend
AM              material trend
CM              matreial trend
A(i)               trend
B(i)               trend
C(i)               trend
;


POSITIVE VARIABLES
BL(i,t)           beta coefficients (positivity quarantees monotonicity)
BK(i,t)           beta coefficients (positivity quarantees monotonicity)
BM(i,t)           beta coefficients (positivity quarantees monotonicity)
;


**** formula's for calculating CSLS***
EQUATIONS
QSSE             objective=sum of squares of errors
QREGRESSION(i,t)        regression equation
QCONCAVITY(i,j,t,s)   concavity constraint
QLCON(t)        labor
QKCON(t)        capital
QMCON(t)        material
QEFF(i,t)       efficiency
;

QSSE..           SS=e=sum(t,sum(i,E(i,t)*E(i,t)));
QREGRESSION(i,t)..      Y(i,t)=e=BL(i,t)*L(i,t)+BK(i,t)*K(i,t)+BM(i,t)*M(i,t)+
(AL*Tr(t)+CL*Tr2(t))*L(i,t)+(AK*Tr(t)+CK*Tr2(t))*K(i,t)+(AM*Tr(t)+CM*Tr2(t))*M(i,t)
-(A(i)+B(i)*Tr(t)+C(i)*Tr2(t))*Y(i,t)+Y(i,t)*E(i,t);
QCONCAVITY(i,j,t,s)..  BL(i,t)*L(i,t)+BK(i,t)*K(i,t)+BM(i,t)*M(i,t)=l=BL(i,t)*L(j,s)+BK(i,t)*K(j,s)+BM(i,t)*M(j,s);
QLCON(t)..  (AL*Tr(t)+CL*Tr2(t))=g=0;
QKCON(t)..  (AK*Tr(t)+CK*Tr2(t))=g=0;
QMCON(t)..  (AM*Tr(t)+CM*Tr2(t))=g=0;
QEFF(i,t)..  A(i)+B(i)*Tr(t)+C(i)*Tr2(t)=g=0;

MODEL CNLS /all/

OPTION limrow    = 0;
OPTION limcol    = 0;
OPTION SOLPRINT  = OFF;
OPTION optcr     = 0.0;
OPTION iterlim   = 10000000;
OPTION reslim    = 10000000;

$libinclude gams2txt


SOLVE CNLS using NLP Minimizing SS;
SSvalue=SS.l;
Evalue(i,t)=E.l(i,t);
BLvalue(i,t)=BL.l(i,t);
BKvalue(i,t)=BK.l(i,t);
BMvalue(i,t)=BM.l(i,t);
ALvalue=AL.l;
CLvalue=CL.l;
AKvalue=AK.l;
CKvalue=CK.l;
AMvalue=AM.l;
CMvalue=CM.l;
Avalue(i)=A.l(i);
Bvalue(i)=B.l(i);
Cvalue(i)=C.l(i);

$libinclude xldump SSvalue C:\GAMS\GAMSFILES\tradesector\cnls_res_PANEL_fixed.xls ss a1:b2
$libinclude xldump Evalue C:\GAMS\GAMSFILES\tradesector\cnls_res_PANEL_fixed.xls E b2:ad15
$libinclude xldump BLvalue C:\GAMS\GAMSFILES\tradesector\cnls_res_PANEL_fixed.xls BL b2:ad15
$libinclude xldump BKvalue C:\GAMS\GAMSFILES\tradesector\cnls_res_PANEL_fixed.xls BK b2:ad15
$libinclude xldump BMvalue C:\GAMS\GAMSFILES\tradesector\cnls_res_PANEL_fixed.xls BM b2:ad15
$libinclude xldump ALvalue C:\GAMS\GAMSFILES\tradesector\cnls_res_PANEL_fixed.xls AL b2:ad15
$libinclude xldump CLvalue C:\GAMS\GAMSFILES\tradesector\cnls_res_PANEL_fixed.xls CL b2:ad15
$libinclude xldump AKvalue C:\GAMS\GAMSFILES\tradesector\cnls_res_PANEL_fixed.xls AK b2:ad15
$libinclude xldump CKvalue C:\GAMS\GAMSFILES\tradesector\cnls_res_PANEL_fixed.xls CL b2:ad15
$libinclude xldump AMvalue C:\GAMS\GAMSFILES\tradesector\cnls_res_PANEL_fixed.xls AM b2:ad15
$libinclude xldump CMvalue C:\GAMS\GAMSFILES\tradesector\cnls_res_PANEL_fixed.xls CM b2:ad15
$libinclude xldump Avalue C:\GAMS\GAMSFILES\tradesector\cnls_res_PANEL_fixed.xls A b2:ad15
$libinclude xldump Bvalue C:\GAMS\GAMSFILES\tradesector\cnls_res_PANEL_fixed.xls B b2:ad15
$libinclude xldump Cvalue C:\GAMS\GAMSFILES\tradesector\cnls_res_PANEL_fixed.xls C b2:ad15

OPTION decimals=6;